'***************************************************************************************************************
'*                                    INTEL DISCLOSURE And COPYRIGHT INFORMATION                              '*
'*                                                                                                            '*  
'*                THIS DOCUMENT AND ALL INFORMATION PROVIDED HEREIN, INCLUDING CODE, IS PROVIDED              '*  
'*                "AS IS" WITH NO WARRANTIES WHATSOEVER, INCLUDING ANY WARRANTY OF MERCHANTABILITY,           '*
'*                NONINFRINGEMENT, FITNESS FOR ANY PARTICULAR PURPOSE, OR ANY WARRANTY OTHERWISE              '* 
'*                ARISING OUT OF ANY PROPOSAL, SPECIFICATION OR SAMPLE.                                       '*
'*                Intel disclaims all liability, including liability for infringement of any proprietary      '*
'*                rights, relating to use of information or code in this document.   Recipient may use        '*
'*                this document and all information herein, including code, but all such use is and shall     '*
'*                be at recipient's sole risk and subject to the disclaimers and limitations of liability     '*
'*                herein.  No other license, express or implied, by estoppel or otherwise, to any             '*  
'*                intellectual property rights is granted herein.                                             '*  
'*                Copyright (c) Intel Corporation 2008. *Third-party brands and names are                     '*  
'*                the property of their respective owners.                                                    '*  
                                                                                                       
'***************************************************************************************************************

' File              :    Team_SetTeamSetting.VBS
' Version           :     1.0
'
'  Purpose :   to set the new values for the team setting
'                   
'
'  Arguments : Team_SetTeamSetting.vbs <TeamIndex SettingName SettingValue> [target username password] [help]
'
'               <TeamIndex>     - Index of the team for which the setting is changed
'               <SettingName>   - The setting for which the new value is set
'               <SettingValue>  - The new value to be set
'               <remote>        - the name of a remote computer; requires the following:
'               <username>      - user name
'               <password>      - password
'
'
'  Instructions for use:
'  =====================
'  1) Execute script by invoking "cscript Team_SetTeamSetting.vbs" from the command line with arguments listed above
'  2) The common script library vbslib.vbs must be located in the same directory
'
'***************************************************************************************************************
   Option Explicit
   On Error Resume Next
   Include "VBSLIB.vbs"

     Const SCRIPT_NAME = "Team_SetTeamSetting.vbs"
     Const SCRIPT_DESCRIPTION = "To set the new value for the team setting"

     'Global variables
     Dim Target, Username, Password
     Dim WbemServices
     Dim sError
     
     Dim TeamIndex, internalTeamIndex
     Dim SettingName, SettingValue
     Dim sResult
     
     
     'Check command line is correct
     If ParseCommandLine(TeamIndex, SettingName, SettingValue, Target, Username, Password) = false then 
          PrintScriptHelp
          Wscript.Quit 0
     End if

     'Connect
     If WMIConnect(WbemServices, "root\Intelncs2", Target, Username, Password, sError) = false then
          Wscript.Echo "Failed to connect to WMI namespace. " & VbNewLine
          wscript.echo "Make sure Intel(R) Network Connections software is installed."
          Wscript.Quit 0
     End if    
    
     Dim TeamList
     
     TeamList = EnumerateTeams(WbemServices, sResult)
     
     ' Check that there are teams on the system
     if IsNothing(TeamList)then
          wscript.Echo "No teams found on the system."
          wscript.quit 0
     end if
     
     ' Subtract 1 since the user is going to give an index based on 
     ' a 1-indexed array and the adapter array is 0-indexed 
     internalTeamIndex = TeamIndex - 1
     
     ' Verify the team specified is a valid index, bail if not
     if (InternalTeamIndex < 0) then
          wscript.echo "Invalid team index. Team index must be greater than 0"
          wscript.quit 0
     elseif (InternalTeamIndex > ubound(TeamList)) then
          wscript.echo "Team index not found: " & InternalTeamIndex
          wscript.quit 0
     end if
     
     ' Display the team
      wscript.Echo Cstr(TeamIndex) & ") " & TeamList(InternalTeamIndex).Caption & " " & VbNewLine
     
      
     dim ret : ret = SetTeamSetting (WbemServices, TeamList(InternalTeamIndex), SettingName, SettingValue, sResult)                         
    
     if ret = true then
          if Len(sResult) > 0 then
               wscript.echo sResult
          else
               wscript.echo "   Successfully set setting: " & SettingName 
          end if
     else
          wscript.echo "   " & sResult 
     end if
 
     wscript.Quit 0
     
'===================================================
' Function       : ParseCommandLine
' Purpose        : Evaluates command line arguments passed to the script and determines If they are correct
' Arguments      :     
'                       
'               sTarget - the name of a remote computer
'               sUserName - the user name for remote auThentication
'               sPassword - the password for remote auThentication
'
' Returns :      True (If the command line has the correct format), False otherwise
' Notes   :      User name can be in the form of either a user name or a Domain\argUserName
'                    'Help' will return false - the script does not need to do anything else
'===================================================
Function ParseCommandLine (byref TeamIndex, byref SettingName, byref SettingValue, byref sTarget, byref sUserName, byref sPassword)

     Err.Clear
     On Error Resume Next
     
     'Capture command line arguments
     Dim cmd_args : Set cmd_args = wscript.Arguments
     
     'Check number of command line arguments and exit If it is not correct
     Select Case cmd_args.count
          Case 1 
               ' if the only command line arg is 'help' return false so the script help will be displayed
               If instr(LCase(cmd_args(0)), "help") >= 0 Then
                    ParseCommandLine = false
                    Exit Function
               End If                         
          Case 3
                if not IsNumeric(cmd_args(0)) OR IsNumeric(cmd_args(1)) then
                   ParseCommandLine = false
                   exit function
                end if
                   TeamIndex = cmd_args(0)
                   SettingName = cmd_args(1)
                   SettingValue = cmd_args(2)
                   ParseCommandLine = True
                   sTarget = "."
                   sUsername = ""
                   sPassword = ""
                   Exit Function
          Case 6
                   if not IsNumeric(cmd_args(0)) OR IsNumeric(cmd_args(1)) then
                    ParseCommandLine = false
                    exit function
                   end if
                   TeamIndex = cmd_args(0)
                   SettingName = cmd_args(1)
                   SettingValue = cmd_args(2)
                   ParseCommandLine = True
                   sTarget = cmd_args(3)
                   sUsername = cmd_args(4)
                   sPassword = cmd_args(5)
                   Exit Function              
     End Select
     
     'Return failure
     ParseCommandLine = False
     
End Function
     

'===================================================
'       Sub : PrintScriptHelp
'   Purpose :  Prints command line help for the user
'                   on how to use this script
'===================================================
Sub PrintScriptHelp
                
      Wscript.Echo "Usage :" & VbNewLine & VbNewLine &_ 
                              "  " & SCRIPT_NAME & " <TeamIndex SettingName SettingValue> [target username password] [help]" & VbNewLine & VbNewLine &_
                              "  Required: " & VbNewLine & VbNewLine &_
                              "    " & TeamIndexString & VbNewLine &_
                              "                   " & TeamGetIndexString & VbNewLine & VbNewLine &_
                             "    " & SettingNameString & VbNewLine &_
     	                      "    " & SettingValueString & VbNewLine & VbNewLine &_
                         OptionalCmdLineArgsString


End Sub
     
' DO NOT REMOVE THIS FUNCTION
Function Include(vbsFile)

     Dim fso, ts, buf, path
     Set fso = CreateObject("Scripting.FileSystemObject")

     path = fso.GetParentFolderName (WScript.ScriptFullName) & "\" & vbsFile

     If fso.FileExists(path) Then  
          set ts = fso.OpenTextFile(path)
          buf = ts.ReadAll()
          ts.Close()
          Executeglobal buf
     Else
          Wscript.Echo "Unable to open include file: " & path
          Wscript.Quit 0
     End If

End function
