'***************************************************************************************************************
'*                                    INTEL DISCLOSURE And COPYRIGHT INFORMATION                              '*
'*                                                                                                            '*  
'*                THIS DOCUMENT AND ALL INFORMATION PROVIDED HEREIN, INCLUDING CODE, IS PROVIDED              '*  
'*                "AS IS" WITH NO WARRANTIES WHATSOEVER, INCLUDING ANY WARRANTY OF MERCHANTABILITY,           '*
'*                NONINFRINGEMENT, FITNESS FOR ANY PARTICULAR PURPOSE, OR ANY WARRANTY OTHERWISE              '* 
'*                ARISING OUT OF ANY PROPOSAL, SPECIFICATION OR SAMPLE.                                       '*
'*                Intel disclaims all liability, including liability for infringement of any proprietary      '*
'*                rights, relating to use of information or code in this document.   Recipient may use        '*
'*                this document and all information herein, including code, but all such use is and shall     '*
'*                be at recipient's sole risk and subject to the disclaimers and limitations of liability     '*
'*                herein.  No other license, express or implied, by estoppel or otherwise, to any             '*  
'*                intellectual property rights is granted herein.                                             '*  
'*                Copyright (c) Intel Corporation 2008. *Third-party brands and names are                     '*  
'*                the property of their respective owners.                                                    '*  
                                                                                                       
'***************************************************************************************************************

' File              :     Team_GetTeamInfo.VBS
' Version           :     1.0
'
'  Purpose : Lists all static information for a given team
'
'  Arguments : Team_GetTeamInfo.vbs <TeamIndex> [target username password, help]
'
'              <TeamIndex>    - Index of the team to enumerate member adapters
'              <remote>       - the name of a remote computer; requires the following:
'              <username>     - user name
'              <password>     - password
'
'
'  Instructions for use:
'  =====================
'  1) Execute script by invoking "cscript Team_GetTeamInfo.vbs" from the command line with arguments listed above
'  2) The common script library vbslib.vbs must be located in the same directory
'
'***************************************************************************************************************
   Option Explicit
   On Error Resume Next
   Include "VBSLIB.vbs"

     Const SCRIPT_NAME = "Team_GetTeamInfo.vbs"
     Const SCRIPT_DESCRIPTION = "Lists all static information for a given team"

    'Global variables
     dim TeamIndex, InternalTeamIndex
     Dim Target, Username, Password
     dim sResult
     Dim WbemServices
     Dim Adapters
     Dim sError
     
     'Check command line is correct
     If ParseCommandLine(TeamIndex, Target, Username, Password) = false then 
          PrintScriptHelp
          Wscript.Quit 0
     End if

     'Connect
     If WMIConnect(WbemServices, "root\Intelncs2", Target, Username, Password, sError) = false then
          Wscript.Echo "Failed to connect to WMI namespace. " & VbNewLine
          wscript.echo "Make sure Intel(R) Network Connections software is installed."
          Wscript.Quit 0
     End if    

     ' Enumerate teams
     dim TeamList
     TeamList = EnumerateTeams(WbemServices, sResult)

     ' Check that there are teams on the system
     if IsNothing(TeamList)then
          wscript.Echo "No teams found on the system."
          wscript.quit 0
     end if

     InternalTeamIndex = TeamIndex - 1

     ' Verify the team specified is a valid index, bail if not
     if (InternalTeamIndex < 0) then
          wscript.echo "Invalid team index. Team index must be greater than 0"
          wscript.quit 0
     elseif (InternalTeamIndex > ubound(TeamList)) then
          wscript.echo "Team index not found: " & TeamIndex
          wscript.quit 0
     end if

     ' We've made it this far so the team exists, display the team name
     wscript.Echo Cstr(TeamIndex) & ") " & TeamList(InternalTeamIndex).Caption & " member adapters:" & VbNewLine

     ' Get the team settings
     dim TeamSettings : set TeamSettings = GetTeamInfo(WbemServices, TeamList(InternalTeamIndex))

     ' If nothing was returned, tell the user and bail
     if IsNothing(TeamSettings ) then
          wscript.echo "   No team Settings found"
          wscript.quit 0
     end if

     ' Loop through and display all settings
     dim setting, value
     for each setting in TeamSettings
          ' if the value is null, we need to change it to '<empty>'
          if IsNothing(setting.value) then
               value = "<empty>"
          else
               value = setting.value
          end if

          if (setting.Name = "TeamingMode") then
               if value = 0 then
                    value = "AFT"
               Elseif value = 1 then 
                    value = "ALB"
               Elseif value = 2 then 
                    value = "SLA"
               Elseif value = 4 then 
                    value = "8023AD"
               Elseif value = 5 then 
                    value = "SFT"
               else
                    value = "Unknown"
               End if
          end if

          ' Show the setting name with its value
          wscript.echo "   " & setting.Name & " - " & Cstr(value)
     next


     wscript.Quit 0
          

     
'===================================================
'  Function : ParseCommandLine
'   Purpose : Evaluates command line arguments passed to the script and determines if they are correct
' Arguments : 
'             TeamIndex - Index of the team to use
'             Target - the machine which will receive the request
'             UserName - the user name passed in the command line
'             Password - the password passed in the command line
'   Returns : True (if the command line has the correct format), False otherwise
'   Notes   : User name can be in the form of either a user name or a Domain\Username
'===================================================
     Function ParseCommandLine (byref TeamIndex, byref Target, byref Username, byref Password)
     
          Err.Clear
          On Error Resume Next
          
          'Capture command line arguments
          dim cmd_args : set cmd_args = wscript.Arguments
     
          'Examine number of arguments
          Select Case cmd_args.count
               Case 1 
                    ' if the only command line arg is 'help' return false so the script help will be displayed
                    If instr(LCase(cmd_args(0)), "help") > 0 Then
                         ParseCommandLine = false
                         Exit Function
                    else
                         if IsNumeric(cmd_args(0)) then
                              TeamIndex = CInt(cmd_args(0))
                              sTarget = "."
                              sUserName = ""
                              sPassword = ""
                              ParseCommandLine = true
                              exit function
                         end if
                    End If   
               Case 4
                    ' Check if the first arg (index #) is not a number or if sClass/sPropertyName is and bail
                    if not IsNumeric(cmd_args(0)) then
                         ParseCommandLine = false
                         exit function
                   end if
                    TeamIndex = CInt(cmd_args(0))
                    Target = cmd_args(1)
                    UserName = cmd_args(2)
                    Password = cmd_args(3)
                    ParseCommandLine = true
                    Exit Function  
          End Select

          ParseCommandLine = false
          
     End Function

     '===================================================
     '       Sub : PrintScriptHelp
     '   Purpose : Prints command line help for the user
     '             on how to use this script
     '===================================================
     Sub PrintScriptHelp
     
          Wscript.Echo "Usage :" & VbNewLine & VbNewLine &_ 
                         "  " & SCRIPT_NAME & " <TeamIndex> [target username password] [help]" & VbNewLine & VbNewLine &_
                         "  Required: " & VbNewLine &_
                         "    " & TeamIndexString & VbNewLine &_
                         "                   " & TeamGetIndexString & VbNewLine & VbNewLine &_
                         OptionalCmdLineArgsString
     End Sub
     
' DO NOT REMOVE THIS FUNCTION
Function Include(vbsFile)

     Dim fso, ts, buf, path
     Set fso = CreateObject("Scripting.FileSystemObject")

     path = fso.GetParentFolderName (WScript.ScriptFullName) & "\" & vbsFile

     If fso.FileExists(path) Then  
          set ts = fso.OpenTextFile(path)
          buf = ts.ReadAll()
          ts.Close()
          Executeglobal buf
     Else
          Wscript.Echo "Unable to open include file: " & path
          Wscript.Quit 0
     End If

End function
